We first started with a three-stage amplifier. We based this circuit on figure 15.1 in the book. We found that there were too many capacitors for our liking. Our second design was an active load differential amplifier to a common emitter BJT. With this design we got an unwanted output at low frequencies. We then switched to a common-drain MOSFET as our output stage. This enabled us to remove both the emitter resistor and the collector resistor left over from the BJT stage. We also removed the coupling capacitors, which greatly reduced the total area and lowered our FOM. We decided to use a Widlar current source for the differential amplifier. Our first current source didn’t supply enough current for the differential stage, so the output was clipped at the positive rail. We modified the current source to supply more current to the differential amplifier. We tried a few different resistor values for the current source until the output stopped clipping. We ended up with a current supply of 1.08 mA.

Our final circuit was an active load differential amplifier with a Widlar current source, and common-drain MOSFET output stage.

FOM = (Power)*(Area)/(Gain @ 50kHz)

= (44.7mW) * (206um²) / (820.6)

= 11.22

= 1176

*Design Project

*Differential to Common Collector Amplifier

VCC 1 0 DC 10.0V

VEE 12 0 DC -10.0V

VS 5 0 SIN (0 2m 50K)

RS 4 5 1K

Q1 2 4 6 CA3096N

Q2 3 0 6 CA3096N

Q3 2 2 1 CA3096P

Q4 3 2 1 CA3096P

Q5 6 7 8 CA3096N

M1 1 3 11 11 CMOSN L=1U W=6U

R1 7 12 10K

R2 7 0 10K

R3 8 12 4K

RL 11 0 1K

.MODEL CA3096N NPN (IS=10.000E-15 BF=466.52 VAF=100 IKF=14.030E-3

+ ISE=74.093E-15 NE=1.6606 BR=.1001 VAR=100 IKR=10.010E-3

+ ISC=10.000E-15 NK=.46898 RC=10 CJE=1.2825E-12 MJE=.33333

+ CJC=786.59E-15 MJC=.33333 TF=490.39E-12 XTF=5.3212 VTF=28.396

+ ITF=.27408 TR=10.000E-9)

.MODEL CA3096P PNP (IS=10.000E-15 BF=94.511 VAF=100 IKF=1.1177E-3

+ ISE=976.47E-15 NE=1.9980 BR=.1001 VAR=100 IKR=10.010E-3

+ ISC=10.000E-15 NK=.53243 CJE=1.4535E-12 MJE=.33333 CJC=3.8474E-12

+ MJC=.33333 TF=24.300E-9 XTF=10.054 VTF=9.7920 ITF=1.2571

+ TR=10.000E-9)

.MODEL CMOSN NMOS LEVEL=3 PHI=0.600000 TOX=1.7800E-08 XJ=0.200000U TPG=1

+ VTO=0.7623 DELTA=7.6940E-01 LD=1.1890E-07 KP=1.2379E-04

+ UO=638.1 THETA=1.2160E-01 RSH=6.5980E+00 GAMMA=0.5942

+ NSUB=4.0030E+16 NFS=7.0730E+12 VMAX=1.9160E+05 ETA=4.3410E-02

+ KAPPA=1.0510E-01 CGDO=3.4599E-10 CGSO=3.4599E-10

+ CGBO=4.1520E-10 CJ=2.6473E-04 MJ=0.9561 CJSW=4.0556E-10

+ MJSW=0.270227 PB=0.800000

.MODEL CMOSP PMOS LEVEL=3 PHI=0.600000 TOX=1.7800E-08 XJ=0.200000U TPG=-1

+ VTO=-0.8814 DELTA=1.2220E+00 LD=4.5410E-08 KP=3.6685E-05

+ UO=189.1 THETA=1.7250E-01 RSH=5.5000E-01 GAMMA=0.4652

+ NSUB=2.4540E+16 NFS=7.7440E+12 VMAX=3.7770E+05 ETA=8.1730E-02

+ KAPPA=9.9830E+00 CGDO=1.3214E-10 CGSO=1.3214E-10

+ CGBO=4.2612E-10 CJ=5.5813E-04 MJ=0.4968 CJSW=2.0919E-10

+ MJSW=0.463227 PB=0.850000

.TRAN .1U 60u 0 .1U

.PROBE

.END